FORUM MP | Cobol : RECUP DONNEES JCL DANS COBOL

COMMUNAUTE MP

Identifiez vous ...

DOMAINE MP

Bavardages

Langages Généraux

Langages Web

Langages DotNet

Autres langages

Dev. Jeux Video

Sécurité

Sys. Exploitation

Graphismes

Logiciels

Réseaux

Bases de données

Méthodologies

Emplois High-tech

Aide juridique

Articles juridiques

FORUM

CHAT MP IRC

Votre pseudo ...

Srv: irc.moteurprog.com

Chan: #MoteurProg

PARTICIPER

Plus de 3500 emplois.

Visiteur MP

RECUP DONNEES JCL DANS COBOL
	Forum : COBOL Sous Catégorie : Aucune Type du sujet : Sujet Normale FAQ : FAQ COBOL
		SUIVI PAR MAIL INACTIF
		SUJET NON RESOLU
		SUJET ACTIF
		N'APPARTIENT PAS A LA FAQ

PAGE : [1]

FORUM COBOL
	Page précedente	Page suivante

SNOOPY
Nouveau membre

Inscrit : 12/10/2004
Messages : 17

#80538 Posté le 17/11/05 à 15:34

OH SECOURS !!! On me demande Comment faire, si cela est possible , de récupérer dans un programme COBOL II BATCH Z/OS les infos suivantes :
- Nom du JCL en cours
- Nom du STEP en cours
- Nom du programme en cours (ca on connait !!)

merci a qui aurait une réponse.

HAUT DE PAGE

Publicité

Inscrit : X
Messages : X

#Aucun

HAUT DE PAGE

milton
Nouveau membre

Inscrit : 05/10/2005
Messages : 25

#80554 Posté le 17/11/05 à 18:56

ben, euh, quand tu lances l'exécution du programme tu lui donnes ces infos en paramètres Smiley

HAUT DE PAGE

HULK77
Modérateur :
- Cobol

Inscrit : 12/08/2004
Messages : 166

#82224 Posté le 09/12/05 à 23:03

Salut l'ami,

Pour compéter les infos de notr ami MILTON,
dans le JCL il vaut déclarer en SYSIN (sous IBM c'est comme cela qu'on appelle les données
que tu veux récupérer dans le programme).
Dans le programme il te faut déclarer en Working
le nom des données à récupérer.

A +
__________________________
Ma fabrique de chemises tourne à plein régime !!!

HAUT DE PAGE

tof91
Nouveau membre

Inscrit : 05/01/2006
Messages : 1

#84364 Posté le 05/01/06 à 12:26

Petit programme cobol qui devrait être utile

IDENTIFICATION DIVISION. 00020000
************************* 00030000
PROGRAM-ID. PBXNONO. 00040000
AUTHOR. ETUBBO. 00050000
DATE-WRITTEN.02/2005. 00060000

* **************************************************** 00080000
* * TEST D'ADRESSAGE MEMOIRE DES DIFFERENTS BLOCK * 00090000
* * PSA BLK - TCB BLK - TIOT BLK * 00090000
* **************************************************** 00110000

* ------------------------------------------------------------- * 00185000
* --- $HISTO HISTORIQUE DES MODIFICATIONS --- * 00186000
* ------------------------------------------------------------- * 00187000
* ! Nø SEQ ! DATE LIV ! OBJET !AUT! * 00188000
* ! MODIF. ! EXPLOIT. ! DE LA MODIFICATION !EUR! * 00189000
* ------------------------------------------------------------- * 00189100
* ! ! ! ! ! * 00189200
* ! ! ! ! ! * 00030000
* ------------------------------------------------------------- * 00189900
ENVIRONMENT DIVISION. 00140000
********************** 00150000
CONFIGURATION SECTION. 00200000
SOURCE-COMPUTER. IBM-370. 00210000
OBJECT-COMPUTER. IBM-370. 00220000
SPECIAL-NAMES. 00230000
DECIMAL-POINT IS COMMA. 00250000
00260000
INPUT-OUTPUT SECTION. 00270000
FILE-CONTROL. 00280000
00290000
* FICHIER EN SORTIE 00300000
* ================= 00310000
SELECT DSNONO1 ASSIGN TO DSNONO1. 00330000

SELECT DSNONO2 ASSIGN TO DSNONO2. 00330000

DATA DIVISION. 00480000
*************** 00490000
FILE SECTION. 00520000
00530000
* DESCRIPTIF DU FICHIER EN ENTREE 00540000
* =============================== 00550000
FD DSNONO1 01220000
LABEL RECORDS STANDARD 01230000
BLOCK CONTAINS 0 RECORDS 01240000
RECORDING MODE IS F 01250000
RECORD CONTAINS 100 CHARACTERS. 01260000
01270000
01 ENR-DSNONO1 PIC X(100). 01280000

FD DSNONO2 01220000
LABEL RECORDS STANDARD 01230000
BLOCK CONTAINS 0 RECORDS 01240000
RECORDING MODE IS F 01250000
RECORD CONTAINS 100 CHARACTERS. 01260000
01270000
01 ENR-DSNONO2 PIC X(100). 01280000

WORKING-STORAGE SECTION. 00980000
************************* 00990000
77 CODE-PROG PIC X(08) VALUE 'PBXNONO '. 00221000
77 PROGRAM-NAME PIC X(08) VALUE 'PBXNONO '. 00221000
77 W-ERR1 PIC X(08) VALUE SPACES. 00221000

01 W-DATE-SYSTEME.
03 W-SS-SYSTEME PIC 9(02).
03 W-AA-SYSTEME PIC 9(02).
03 W-MM-SYSTEME PIC 9(02).
03 W-JJ-SYSTEME PIC 9(02).

01 W-DATE-JOUR.
03 W-JJ-JOUR PIC 9(02).
03 FILLER PIC X VALUE '.'.
03 W-MM-JOUR PIC 9(02).
03 FILLER PIC X VALUE '.'.
03 W-SS-JOUR PIC 9(02).
03 W-AA-JOUR PIC 9(02).

COPY DWTILT. 02400000

01 FILLER. 08270000
05 OS-EOJ PIC X(04) VALUE ZERO. 08280000

01 MESS-TILT PIC X(67) VALUE SPACE.

**************************************************
* WORK SPECIFIQUE POUR ADRESSAGE MEMOIRE *
**************************************************
01 POINTEUR-A-ZERO PIC S9(08) BINARY VALUE +0.
01 PSA-POINTER REDEFINES POINTEUR-A-ZERO, POINTER.

* CE POINTEUR SERVIRA D'INDEX DE BALAYAGE A TRAVERS LES
* ENTREES DE LA TIOT.

01 INDEX-DU-TIOT PIC S9(08) BINARY VALUE +0.
01 TIOT-POINTER-TRAVAIL REDEFINES INDEX-DU-TIOT, POINTER.

LINKAGE SECTION. 08310000
***************** 08320000
* POUR ALIGNER LE BLOCK PSA (PREFIXED SAVE AREA) SUR UNE FRONTIERE
* DE DOUBLE MOT
01 ALIGN-PSA PIC 9(16) BINARY. 08330000
01 PSA-BLOCK. 08330000
05 FILLER PIC X(536). 08330000
05 TCB-POINTER POINTER. 08330000
* TCB ( TASK CONTROL BLOCK )
01 TCB-BLOCK. 08330000
05 FILLER PIC X(012). 08330000
05 TIOT-POINTER POINTER. 08330000
* TIOT ( TASK INPUT/OUTPUT TABLE )
01 TIOT-BLOCK. 08330000
05 TIOT-JOBNAME PIC X(08). 08330000
05 TIOT-STEPNAME PIC X(08). 08330000
05 TIOT-PROCNAME PIC X(08). 08330000
01 TIOT-ENTREE. 08330000
05 TIOT-UNE-ENTREE. 08330000
10 FILLER PIC X(04). 08330000
10 TIOT-DDNAME PIC X(08). 08330000
10 FILLER PIC X(05). 08330000
10 UCB-ADDRESS PIC X(03). 08330000
88 NULL-UCB VALUE LOW-VALUES. 08330000
05 FILLER PIC X(04). 08330000
88 END-OF-TIOT VALUE LOW-VALUES. 08330000
08330000
PROCEDURE DIVISION.
********************
MODULE-DIRECTEUR SECTION.
**************************
PERFORM AA0000-INIT-GENERALE.

PERFORM ZZ0000-FIN-TRAITEMENT.

FIN.
EXIT.

************************************************************
* INITIALISATION GENERALE *
************************************************************
AA0000-INIT-GENERALE SECTION.
*******************************
MOVE 'PBXNONO ' TO PROGRAM-NAME.

MOVE FUNCTION CURRENT-DATE (1:8) TO W-DATE-SYSTEME.
MOVE W-JJ-SYSTEME TO W-JJ-JOUR.
MOVE W-MM-SYSTEME TO W-MM-JOUR.
MOVE W-SS-SYSTEME TO W-SS-JOUR.
MOVE W-AA-SYSTEME TO W-AA-JOUR.

DISPLAY '********************************************'.
DISPLAY '*** PBXNONO1 LE ' W-DATE-JOUR ' ***'.
DISPLAY '********************************************'.

***************************************************************
* RECHERCHE EN MEMOIRE MVS DU NOM DU JOB, DU STEP ET DES *
* DDNAME DES FICHIERS RELATIFS A CE PROGRAMME *
***************************************************************
*
* LE BLOCK PSA A UNE ADRESSE EN MEMOIRE A 0. ON VA DONC
* POSITIONNER LE PSA-BLOCK A UNE TELLE ADRESSE.
*
SET ADDRESS OF PSA-BLOCK TO PSA-POINTER.
SET ADDRESS OF TCB-BLOCK TO TCB-POINTER.
SET ADDRESS OF TIOT-BLOCK TO TIOT-POINTER.
SET TIOT-POINTER-TRAVAIL TO TIOT-POINTER.

DISPLAY '*** JOBNAME = ' TIOT-JOBNAME ' ***'.
DISPLAY '*** STEPNAME = ' TIOT-STEPNAME ' ***'.
DISPLAY '*** PROCNAME(STEPNAME) = ' TIOT-PROCNAME ' ***'.

* ON FAIT POINTER LE POINTEUR SUR LA ZONE TIOT-ENTREE.
COMPUTE INDEX-DU-TIOT = INDEX-DU-TIOT + LENGTH OF TIOT-BLOCK.
SET ADDRESS OF TIOT-ENTREE TO TIOT-POINTER-TRAVAIL.
* ON VA BALAYER LE TIOT TANT QUE L'ON TROUVE UN DDNAME.
PERFORM UNTIL END-OF-TIOT
IF TIOT-DDNAME(1:1) = 'D'
DISPLAY 'DD NAME = ' TIOT-DDNAME
END-IF
COMPUTE INDEX-DU-TIOT = INDEX-DU-TIOT +
LENGTH OF TIOT-UNE-ENTREE
SET ADDRESS OF TIOT-ENTREE TO TIOT-POINTER-TRAVAIL
END-PERFORM.
IF TIOT-DDNAME(1:1) = 'D'
DISPLAY 'DD NAME = ' TIOT-DDNAME
END-IF.

OPEN OUTPUT DSNONO1.
OPEN OUTPUT DSNONO2.

FIN.
EXIT.

XY0000-ABANDON-MODULE SECTION.
*******************************
DISPLAY MESS-TILT.

PERFORM TILT
THRU FIN-TILT.

FIN.
*****
EXIT.

************************************************************
* FIN DE TRAITEMENT *
************************************************************

ZZ0000-FIN-TRAITEMENT SECTION.
*********************************
DISPLAY ' '.

CLOSE DSNONO1.
CLOSE DSNONO2.

MOVE '0000' TO OS-EOJ
PERFORM 9980-OS-CALL-EOJ.

FIN.
*****
EXIT.

BIDON1 SECTION.
***************
COPY PCTILT.

FIN.
EXIT.

9980-OS-CALL-EOJ SECTION.
**************************
CALL 'EOJ' USING OS-EOJ.
GOBACK.

9990-END-SOURCE.
*****************
00010000
BIDON2 SECTION.
***************

FIN.
EXIT.

HAUT DE PAGE

lmlarge
Nouveau membre

Inscrit : 16/01/2006
Messages : 17

#85292 Posté le 16/01/06 à 10:17

ton api cobol est pas mal, mais pas sur que ce soit release dependant, et pas facile a maintenir par un quidam add1toiste.
je te recommande un s/pgm asm avec macro extract syteme...tiot(pas besoin d'être apf) .
là tu es independant et portable.
un pgm asm pour ca notamment c'est tres simple a faire. Et puis tous les besoins specifiques d'un pgm ne sont pas aussi facilement developpable en cobol en tous cas ne pas le laisser croire.a+

HAUT DE PAGE

lmlarge
Nouveau membre

Inscrit : 16/01/2006
Messages : 17

#85420 Posté le 17/01/06 à 11:54

si tu es sous mvs-zos ces infos seront retourné éesa l'aide d'un sous/prog.
si tu es toujours interessé je reprend lundi(23/01) le boulot je peux te faire passer le s/pgm asm qui retourne ces infos.
mon e-mail: prujajarge@hotmail.com
michel.large@ca-sudmed.fr
j'ai plein d'outil qui peuvent t'interesser
a+

HAUT DE PAGE

dchristensen
Nouveau membre

Inscrit : 13/07/2007
Messages : 1

#138340 Posté le 13/07/07 à 19:14

Would it be possible to obtain or see a listing of the two copybooks used in the sample program?

Thanks!

Dave

HAUT DE PAGE

HULK77
Modérateur :
- Cobol

Inscrit : 12/08/2004
Messages : 166

#138523 Posté le 17/07/07 à 13:41

HI,

Can you clarify your question.
That want you to have as listing?

best regard

HULK77
__________________________
Ma fabrique de chemises tourne à plein régime !!!

HAUT DE PAGE


	Page précédente	Page suivante
FORUM COBOL

PAGE : [1]

.: Site Web développé par Julien Pichot et l'équipe MPWG avec www.evolvia-web.com :.